「うんのさん」の例文を翻訳の自習用素材に変える方法

2016年07月07日

「うんのさんの辞書」こと『ビジネス技術実用英語大辞典V5』の例文を、翻訳の自習用素材として手軽に活用するためのAHKスクリプトを作ってみました。自分で指定した見出し語の例文を、次のような形でテキストファイルに抜き出して、単語レベルや単文レベルの訳出練習に使うことができます。

160707_unnosan.png

通常の辞書ブラウザの画面上だと、訳語や訳例が併記されているので、眺めただけでなんとなく理解できた気になるのですが、こうして文単位で抜き出して、自分の頭で訳を考えてみると、また全然違うのではないかと思います。
(上の例は英文のみ抽出していますが、日本語文のみや、英日併記の形で抜き出すこともできます)。

今回作ったスクリプトは、前回の記事で紹介したebwincの使用例のひとつです。検索結果を辞書ブラウザから手作業でコピペして整形するという方法でも、上記のようなテキストはわりと簡単に作れるのですが、その作業を自動化して、大幅に手間を省くことができます。

なお、『ビジネス技術実用英語大辞典V5』の購入者が、例文をテキスト化して自らの学習に使う行為は、使用条件上、特に問題ないものと思われます。本記事の末尾に転載した使用条件の条項をご確認ください。

必要なもの

下準備

EBWin4に『ビジネス技術実用英語大辞典V5』を登録したうえで、何番目の辞書グループの何番目の辞書として登録したかを確認してください。

スクリプト

コードは次のとおりです。赤字の部分をお使いの環境や用途に合わせて修正したうえで(下で説明)、お好きなフォルダにお好きなファイル名(拡張子は「.ahk」)で保存して実行してください。

ebwinc := "C:\Program Files (x86)\EBWin4\ebwinc.exe"
param := "/G=0 /#=4"
outputfile := A_Desktop . "\" . "海野さん例文集.txt"

+^u::
    ; 対象の見出し語を入力してもらう
    InputBox, word, 海野さん例文抽出, 見出し語(英語または日本語)を入力してください
    if (ErrorLevel || word == "") {
        return
    }
    
    ; 入力された文字列をebwinc.exeに送って辞書を検索し、結果をクリップボードに取り込む
    clipbkup := ClipboardAll
    Clipboard := ""
    RunWait, % comspec . " /c ""chcp 65001 & """ . ebwinc . """ " . param . " """ . word . """ | Clip""", , min
    result := Clipboard
    Clipboard := clipbkup

    ; 結果を整形する
    result := RegExReplace(result, "`am)^[^◆].+\R", "")
    result := RegExReplace(result, "`am)^◆(.+) (.+)$", A_YYYY . "/" . A_MM . "/" . A_DD . "`t" . word . "`t$1" )
    result := RegExReplace(result, "`a)\R\R", "`r`n")
    result := RegExReplace(result, "&lt;", "<")
    result := RegExReplace(result, "&gt;", ">")

    ; 結果をファイルに書き込む
    if (result) {
        FileAppend, %result%, %outputfile%, UTF-8
        TrayTip, 海野さん例文抽出, % "「" . word . "」の例文をファイルに追加しました", 10, 1
    } else {
        SoundPlay, *-1
    }

    return

スクリプトの修正箇所

上記スクリプトで赤字になっている5カ所は、お使いの環境や用途に合わせて、それぞれ次の要領で修正してください。

●1行目の「ebwinc := "C:\Program Files (x86)\EBWin4\ebwinc.exe"」
→ ebwinc.exeのフルパス(EBWin4のインストール先フォルダの中にあります)

●2行目の「param := "/G=0 /#=4"」
→ EBWin4で『ビジネス技術実用英語大辞典V5』を登録したグループ番号と辞書番号
(「/G=○」は辞書グループ番号で、1つ目のグループなら0、2つ目なら1、3つ目なら2、…というふうに指定します。「/#=0」は辞書番号で、グループ内の1つ目の辞書なら0、2つ目なら1、…というふうに指定します)。

●3行目の「outputfile := A_Desktop . "\" . "海野さん例文集.txt"
→ 抽出した例文を出力するテキストファイル名。このままにすると、デスクトップに「海野さん例文集.txt」というファイルを作成し、その中に記録します。別のファイルにする場合は、フルパスを " " 囲みで指定してください。

●4行目の「+^u::」
→ 抽出対象の見出し語を入力するときに使うホットキー。このままにすると、「Ctrl+Shift+U」となります。

●一番長い「result := 〜」という行の中の「"`t$1"」という部分
→ 抽出する文の種類をここで指定しています。このままにすると英文のみ抽出します。ここを「`t$2」に変えると日本語文のみ、「`t$1`t$2」に変えると英日併記(タブ区切り)で抽出できます。

使い方

次のような手順で、(1)要練習の単語を順次ピックアップし、(2)後でまとめて練習する、という使い方を想定しています。

(1)指定したホットキー(上記スクリプトのままならCtrl+Shift+U)を押すと、入力ボックスが表示されるので、例文を抽出したい単語(見出し語)を入力してください。英語でも日本語でもかまいません。翻訳の仕事や学習の中で、「要練習」と思う単語が出てきたときに、メモ感覚でそのつどサッと入力しておくとよいと思います(放っておくと忘れてしまうため)。

「要練習」というのは、たとえば、意味がクリアにつかめていない単語、特定の訳語をワンパターンであててしまいがちな単語、自分の中で訳し方の選択肢が少ない単語、訳語の選定に迷いがちな単語、なんとなく苦手意識がある単語、(学習中の方なら)翻訳の課題や授業で出てきた単語、などなどです。

見出し語を入力すると、その項目の例文が、上記スクリプト内で指定した名前のテキストファイルに書き込まれます。(上記スクリプトのままなら、デスクトップ上の「海野さん例文集.txt」)。ファイルは上書きではなく、末尾に追加する形で書き込まれます。

(2)後で時間があるときに、一連の例文を素材として、じっくり練習を進めていくとよいと思います。他の英和辞典や英英辞典を丹念に引いて訳を考え出したうえで、海野さんの訳例と比べてみるとよいのではないでしょうか。

こんな感じで進めていけば、自分専用のよい練習問題集が出来上がり、単語レベル・単文レベルの訳出力をコツコツと強化できるのではないかと思います。

ちなみに、テキストはタブ区切りですので、Excelに貼り付けて使うという手もあります。

辞典データの著作権・使用条件について

『ビジネス技術実用英語大辞典V5』の取扱説明書では、辞典データの使用条件について、次のように規定されています。

【著作権について】この辞典の著作権は、著者である海野文男と海野和子に帰属します。この辞典データを、「個人による使用の範囲」(*次項で定義)を超えて使用することは、複製、ネットワーク共用、ネットワーク公開、転載、二次使用、再配布、販売、レンタル、その他いかなる形態であっても、著作者に無断で行うことを固く禁じます。なお、購入者個人の目的の範囲内で使用する限りにおいては、データ形式の変換などの加工を、購入者自身が行ってもよいものとします。

最後の一文を読む限り、『ビジネス技術実用英語大辞典V5』の購入者が例文をテキスト化して自らの学習に使う行為は、使用条件上、問題ないものと思われます。

取扱説明書に記載された使用条件の内容をあらためてご確認のうえ、適切なご使用をお願いいたします。

posted by 内山卓則 at 22:08 | スクリプト・プログラム